Where is the Plotters Collection

r2004

Can someone tell me where the collection of all defined plotters would be
located?

Thanks alot,

Don

 

(vla-get-plotconfigurations
(vla-get-activedocument
(vlax-get-acad-object)))

?

 

Actually, I've tried that but it only returns a collection one item in
length (at least on my machine).

What I'm trying to do is to get the same list that you see in "Page Setup /
Plot Device / Plotter Configuration / Name" dropdown list.

Thanks,

Don

 

In that case,

; based on an example by Doug Broad
; obtain a list of available printers/plotters
; return: list of strings or nil
(defun getPlotDevices (/ hide layout)
(if (setq hide (= "1" (getenv "HideSystemPrinters")))
(setenv "HideSystemPrinters" "0") )
(setq layout (vla-get-activelayout *doc*))
(vla-refreshplotdeviceinfo layout)
(if hide (setenv "HideSystemPrinters" "1"))
(vlax-invoke layout 'getplotdevicenames)
)


; file dependencies
; getPlotDevices.lsp
(defun getPC3Devices (/ lst)
(if (setq lst (getPlotDevices))
(vl-remove
"None"
(vl-remove-if-not
'(lambda (x) (wcmatch x "*.pc3"))
lst
)
)
)
)

 

Hey Cool!

I didn't know about the environment setting.

Thanks!

Don