vlax-catch-all-apply

Hi

How to correct use of vlax-catch-all

I have this routine
(DEFUN cRUCOMPLE()
(VL-LOAD-COM)
(SETQ NVAL 0 NMAX 1000)
; (SETQ p (vl-catch-ALL-APPLY 'VLAX-CREATE-OBJECT '"COMPLE2.COXMPLE2"))
(SETQ P (VL-CATCH-ALL-APPLY (SETQ OBJ (VLAX-CREATE-OBJECT "COMPLEX.COXMPLE2"))))
(IF (vl-catch-all-error-p P)
(PRINC "\nCAN´T CREATE OBJECT")
)
(WHILE (< NVAL NMAX)
(PRINC NVAL)
(if (/= (VLAX-INVOKE OBJ 'Comple) 1)
(alert "error")
)
(setq nval (+1 nval))
)
)
I´m trying to keep program runing and send an error message if the object can´t be created.

Thank for the help
Jorge Matheus

 

Hi Jorge,

The commented line in the code is in the right direction but with a
correction.
(SETQ p (vl-catch-ALL-APPLY 'VLAX-CREATE-OBJECT '("COMPLE2.COXMPLE2")))

Or
(SETQ p (vl-catch-ALL-APPLY 'VLAX-CREATE-OBJECT (list "COMPLE2.COXMPLE2")))

Also should work.

The uncommented (setq p (vl-catch-all-apply (setq obj ...) won't work. It's
a syntax error.

 

Thank for your answered PG

But it doesn't work

Have you loaded it ??

It should give you an error because comple2.comple2 is not a registered aplication.

Thank

 

Hi Jorgematheus schrieb:

You've to cover 'vl-catch-all-apply' with 'vl-catch-all-error-p':

Code:

(if (vl-catch-all-error-p
(setq p (vl-catch-all-apply
'vlax-create-object
'("COMPLE2.COXMPLE2")
)
)
)
(princ "\nCan't create object.")
(DoTheOtherStuff)
)

Cheers

 

Jorge,

I use this function as a means to catch errors when using vl* functions:

;;f:vlerr simplified error catching routine for vl-catch*
;;f:vlerr usage (setq en (f:vlerr 'vla-get-Area (list en) nil))
;;f:vlerr tag = true for debugging: princes error message

(defun f:vlerr (fun lst tag / ret)
(if (vl-catch-all-error-p (setq ret (vl-catch-all-apply fun lst)))
(if tag
(progn
(princ (strcat "\n" (vl-catch-all-error-message ret) "\n"))
(princ fun)
(princ lst)
nil
)
nil
)
(if (not ret) (setq ret T) ret)
)
(if (= (type ret) 'VL-CATCH-ALL-APPLY-ERROR) (setq ret nil))

ret)



However, in your case, the VLAX-CREATE-OBJECT returns nil if it can't create the application - so you could just use
(cond
((not (setq obj (VLAX-CREATE-OBJECT "COMPLE2.COXMPLE2") ))
(alert "Could not create COMPLE2.COXMPLE2.")
)
(T ...)
)

You could also use the vb method GetInterfaceObject to return more specific information - load f:vlerr and try this:

(f:vlerr 'vla-GetInterfaceObject (list (vlax-get-acad-object) "COMPLE2.COXMPLE2") T)


Peter

 

Thank all for the help

 

Wouldn't this work? Looks like if the object was not created, nil is
returned.

(if (not (setq obj (vlax-create-object "complex.coxmple2")))
(princ "\nCould not create object!")
)

--
Ken Alexander
Acad2004
Windows XP

"We can't solve problems by using the same kind
of thinking we used when we created them."
--Albert Einstein

 

Yes it does. I have done before.

It happen to me one in while, i get into a problem and tried the hard way.

Einstein was really right

The good: I learned additional thing.

Thank

 

I usually go the hard way too.

Glad it helped.

--
Ken Alexander
Acad2004
Windows XP

"We can't solve problems by using the same kind
of thinking we used when we created them."
--Albert Einstein