Save and restore VAR

Hi everybody,
sorry for my poor english, i can write this better in italian!

So, i wold like to change the current color ad layer, draw a mline trugh
drawing adn when finishing restore the previous state of layer and colour.
I write this code, but i don't know how is it possible to invoke restore
routine after mline command.

Thanks to all, very fine NG

Diego.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;SOC

(defun restore()
(setvar "cecolor" oldcol)
(setvar "clayer" oldlay)
)
(defun save()
(setq oldcol (getvar "cecolor")) ;; save current color
(setq oldlay (getvar "clayer")) ;; save current layer
)
(defun C:mpele (/)
(save)
(setvar "cecolor" "bylayer")
(setvar "clayer" "PASSERELLE ELE")
(command "mline" "j" "zero")
(restore)
)
;;;EOC
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

 

Hi KirkONE,try this
(defun restore()
(setvar "cecolor" oldcol)
(setvar "clayer" oldlay)
)
(defun save()
(setq oldcol (getvar "cecolor")) ;; save current color
(setq oldlay (getvar "clayer")) ;; save current layer
)
(defun C:mpele (/ nlayer pt1 pt2)
(save)
(setvar "cecolor" "bylayer")
;(setvar "clayer" "PASSERELLE ELE")
(setq nlayer "PASSERELLE ELE")
(if (not (tblsearch "layer" nlayer))
(command "layer" "n" nlayer "")
(princ "That layer already exists.")
)
(setq pt1 (getpoint "\nCLICK LOCATION FOR FIRST OBJECT: "))
(setq pt2 (getpoint "\nCLICK LOCATION FOR SECOND OBJECT: "))
(command "mline" pt1 pt2 "")
(restore)
)

 

OK, i think this work fine but i must draw a Mline with very lot of
point, and not ever the same number of it.

 

Try this model..

(defun restore()
(setvar "cecolor" oldcol)
(setvar "clayer" oldlay)
)
(defun save_lay ()
(setq oldcol (getvar "cecolor")) ;; save current color
(setq oldlay (getvar "clayer")) ;; save current layer
)
(defun C:mpele (/)
(save_lay)
(setvar "cecolor" "bylayer")
(setq nlayer "PASSERELLE ELE")
(if (not (tblsearch "layer" nlayer))
(command "_layer" "m" nlayer "")
)
(command "mline" "j" "zero")
(while (= (logand (getvar "cmdactive") 1) 1)
(command pause)
); while
(restore)
)

Bob

 

SIMPLY PERFECT!!!!
tnx

diego

 

Diego,
Glad to help out.
http://www.bobscadshop.com

Bob