replacing or adding dimstyles from another drawing

Joe Burke · Mar 21, 2005

Tom,

You're welcome.

It turned out more complicated than I initially expected. I was tempted to trash it a
couple times. But given I figured it could be done, I have a hard time letting go of
something which just needs more thought.

Get the revised version recently posted. I can't be sure it covers all conditions,
but I trust you'll let me know if it doesn't.

Regards
Joe Burke

Tom Hanley · Mar 21, 2005

I noticed that you noted it will lose associativity on existing dimensions.
We aren't using transpatial associativity (dimensioning in paperspace) yet
but I would like to use it if LDT would support it and the peole we share
files ever update to a version that recognizes it. You should save that
revision for the regi$tered version

Thanks again for the update...

Joe Burke said:

Tom and Dave,

Revised version enclosed.

Fixes a bug and tweaks a few things. Source file can be DWG, DWT or DWS.
Existing dimensions/leaders in model space and layouts are updated.

Let me know if you find any problems.

Code:

;; Joe Burke - revised version 3/20/2005
;; Import dimstyles which don't exist in the active file.
;; Update dimstyles in the active file which exist in both files.
;; Note: existing associated dimensions will be disassociated.
(defun c:ImportDimStyles (/ *error* GetDoc doc targstyles oldcnt fullpath
srcdoc srcstyles actdimstyle name exstnamelst
srcnamelst copylst endnamelst duplst
tempstyle namelst newcnt)

;;local functions
;;-------------------------------------------------
(defun *error* (error)
(cond
((not error))
((wcmatch (strcase error) "*QUIT*,*CANCEL*"))
(T (princ (strcat "\nERROR: " error)))
)
(if
(and
srcdoc
(not (vlax-object-released-p srcdoc))
)
(vlax-release-object srcdoc)
)
(if
(and
tempstyle
(not (vlax-erased-p tempstyle))
)
(vla-delete tempstyle)
)
(vla-EndUndoMark doc)
(princ)
) ;end error

;Returns either a doc from the documents collection
;or an ObjectDBX doc.
;Note, versions earlier than 2004 need modified code
;if axdb15.dll is not registered.
(defun GetDoc ( path / *acad* documents srcdoc )
(setq *acad* (vlax-get-acad-object)
documents (vla-get-documents *acad*)
)
;check the documents collection
(vlax-for x documents
(if (= path (vlax-get x 'FullName))
(setq srcdoc x)
)
)
;or use ObjectDBX
(if (null srcdoc)
(progn
(setq srcdoc
(vla-GetInterfaceObject *acad* "ObjectDBX.AxDbDocument.16")
)
(vla-open srcdoc path)
)
)
srcdoc
) ;end
;;-------------------------------------------------

(setq doc (vla-get-activedocument (vlax-get-acad-object)))
(vla-EndUndoMark doc)
(vla-StartUndoMark doc)

(setq targstyles (vla-get-DimStyles doc)
oldcnt (vlax-get targstyles 'Count)
fullpath (getfiled "Select Source File"
(getvar "dwgprefix") "dwg;dwt;dws" 0)
)

(if (not fullpath)
(progn
(princ "\nSource document not selected. Exiting... ")
(exit)
)
)

(setq srcdoc (GetDoc fullpath)
srcstyles (vla-get-dimstyles srcdoc)
actdimstyle (vlax-get doc 'ActiveDimStyle)
)

;list the dimstyle names in each document and determine
;what the name list in target doc should be after import
(vlax-for x targstyles
(setq exstnamelst (cons (vlax-get x 'Name) exstnamelst))
)
(vlax-for x srcstyles
(setq copylst (cons x copylst))
(setq name (vlax-get x 'Name))
(setq srcnamelst (cons name srcnamelst))
(if (not (vl-position (strcase name) (mapcar 'strcase exstnamelst)))
(setq endnamelst (cons name endnamelst))
(setq duplst (cons name duplst))
)
)
(setq endnamelst (append exstnamelst endnamelst))

;rename dimstyles to be updated
(foreach x duplst
(vlax-put (vla-item targstyles x) 'Name (strcat "%%" x))
)

;copy all source doc dimstyles to target doc
(vlax-invoke srcdoc 'CopyObjects copylst targstyles)

(vlax-release-object srcstyles)
(vlax-release-object srcdoc)

(if duplst
(progn  ;------------

;add a temporary dimstyle and make it the active dimstyle
(setq tempstyle (vlax-invoke targstyles 'Add "tempdimensionstyle"))
(vlax-put doc 'ActiveDimStyle tempstyle)

;copy dimstyle settings from source style to target style
(foreach x duplst
(vla-CopyFrom
(vla-item targstyles (strcat "%%" x))
(vla-item targstyles x)
)
;rename each temporary style
(vlax-put (vla-item targstyles x) 'Name (strcat "##" x))
)

;update duplicate names list
(setq duplst (mapcar '(lambda (a) (strcat "##" a)) duplst))

;first delete temp substyles
(vlax-for x targstyles
(setq name (vlax-get x 'Name))
(if
(and
(vl-position name duplst)
(vl-string-search "$" name)
)
(vl-catch-all-apply 'vla-delete (list x))
)
)

;then delete temp parent styles
(vlax-for x targstyles
(setq name (vlax-get x 'Name))
(if (vl-position name duplst)
(vl-catch-all-apply 'vla-delete (list x))
)
)

;rename styles to original names
(vlax-for x targstyles
(setq name (vlax-get x 'Name))
(if (vl-string-search "%%" name)
(vlax-put x 'Name (vl-string-left-trim "%" name))
)
)

;update existing dimensions with new style
;settings in Model space and layouts
(if (ssget "X" (list (cons 0 "DIMENSION")))
(vlax-for x (vlax-get doc 'ActiveSelectionSet)
(vla-update x)
)
)

;restore the active dimstyle
(vlax-put doc 'ActiveDimStyle actdimstyle)
;delete the temporary dimstyle
(vl-catch-all-apply 'vla-delete (list tempstyle))

) ;progn ------------
) ;if

;Reports:
;get the updated list of dimstyle names and compare
;with anticipated list: endnamelst
(vlax-for x targstyles
(setq namelst (cons (vlax-get x 'Name) namelst))
)

;option
;(textscr)

(if (equal (acad_strlsort namelst) (acad_strlsort endnamelst))
(princ "\nImport operation was successful. ")
(princ "\nImport encountered a problem. Undo or check dimstyles. ")
)

(if (< oldcnt (setq newcnt (vlax-get targstyles 'Count)))
(princ (strcat "\nNumber of dimstyles added: " (itoa (- newcnt
oldcnt))))
)

(if duplst
(princ (strcat " Number of dimstyles updated: " (itoa (length
duplst))))
)

(*error* nil)
) ;end

;; -----------------------------
;; shortcut
(defun c:IDS () (c:ImportDimStyles))
;; -----------------------------

Click to expand...

Aeo.Z · Mar 26, 2005

ctrl + 2
design center
to drag into your drawing

replacing or adding dimstyles from another drawing

Joe Burke Guest

Tom Hanley Guest

Aeo.Z Guest

Want to reply to this thread or ask your own question?

Changing dimstyles unwanted

Turning ON the Alternate Unints for all DIMSTYLES

Replacing an item in a list with another

dimstyles/autolayer

VB question: replacing parts in drawing.

Replacing Drawing Sheet on Multiple Sheet Drawing Package

set DIMSCALE for all dimstyles at once? - acad 2002

toolbars, dimstyles, and linetypes

replacing or adding dimstyles from another drawing

Joe Burke Guest

Tom Hanley Guest

Aeo.Z Guest

Want to reply to this thread or ask your own question?

Useful Searches