renaming blocks

I'm trying to rename some specific blocks, it appears to be in a cont. loop though. Can anyone help.

(defun rename ()
(setvar "cmdecho" 0)
(setq nextblock (tblnext "block" T))
(setq blocklist (list "CWSURF" "WSURF" "CHAIR"))
(setq blocknew ( list "CWSURF_OLD" "WSURF_OLD" "CHAIR_OLD"))
(while nextblock
(setq nameofblock (cdr (assoc 2 nextblock)))
(if (member nameofblock blocklist)
(progn
(setq newnameofblock (strcat nameofblock "_old"))
(if (/= nextblock blocknew)
(command ".rename" "b" nameofblock newnameofblock)
(setq nextblock (tblnext "block"))
)
)
)
)
)
;

 

try this out....
Jeff

(defun rename (/ nextblock blocklist blocknew nameofblock newnameofblock)
;(setvar "cmdecho" 0) ; shouldn't change this without setting it back
(setq nextblock (tblnext "block" T))
(setq blocklist (list "CWSURF" "WSURF" "CHAIR"))
(while nextblock
(setq nameofblock (cdr (assoc 2 nextblock)))
(if (member nameofblock blocklist)
(progn
(setq newnameofblock (strcat nameofblock "_old"))
(command ".rename" "b" nameofblock newnameofblock)
)
)
(setq nextblock (tblnext "block"))
)
(princ)
)

 

Thanks.

I get a error:

; error: bad argument type: stringp nil

 

Hmm, not sure why as it works fine here.
But here's a different one to try:

(defun rename2 ()
(vl-load-com)
(vlax-for blk (vla-get-blocks
(vla-get-activedocument
(vlax-get-acad-object)))
(if (wcmatch (vla-get-name blk) "CWSURF,WSURF,CHAIR")
(vla-put-name blk (strcat (vla-get-name blk) "_old"))
)
)
(princ)
)

Jeff

 

In original code:
(if (/= nextblock blocknew)
(command ".rename" "b" nameofblock newnameofblock)
(setq nextblock (tblnext "block"))
.........
only increments to next block (tblnext)..when if fails..
should increment all the time. Try:
(if (/= nextblock blocknew)
(command ".rename" "b" nameofblock newnameofblock))
(setq nextblock (tblnext "block")
......... instead

Bob