Outlook message box

Discussion in 'AutoCAD' started by Marcel Goulet, Jul 19, 2004.

  1. Marcel Goulet

    Marcel Goulet Guest

    Hi,

    From my own menu in AutoCAD, I would like to use a lisp or vlisp program to activate an Outlook new message box with the sending address field and object field prefilled.

    Thanks.
     
    Marcel Goulet, Jul 19, 2004
    #1
  2. Marcel Goulet

    petersciganek Guest

    Marcel -

    You should be able to modify this code to suite your needs:

    (defun c:maildwgname ( / app end ml tx fl)
    (vl-load-com)
    (if (not (setq app (vlax-get-object "Outlook.Application")))
    (setq app (vlax-get-or-create-object "Outlook.Application")
    end T
    );setq
    );if

    (if app
    (progn
    (setq fl (strcat (getvar "DWGPREFIX")(getvar "DWGNAME"))
    tx (strcat "<HTML><HEAD><BODY><P>" fl "</p> <P>Click <A href=\"file://"
    (getvar "DWGPREFIX") "\">HERE</a> to open directory. </p></body></html>")
    );setq
    (setq ml (vlax-invoke-method app 'CreateItem 0))
    (vlax-put-property ml 'Subject fl)
    (vlax-put-property ml 'HTMLBody tx)
    (vlax-invoke-method ml 'Display 1)
    (if end (vlax-invoke-method app 'Quit))
    (mapcar 'vlax-release-object (list app ml))
    (gc)
    );progn
    (alert "Problem opening Outlook.")
    );if
    (princ));defun

    This simply opens a new mail item and adds the current path directory as the subject line and as a hyperlink. This works for Outlook 2002.

    Peter
     
    petersciganek, Jul 19, 2004
    #2
  3. Marcel Goulet

    Marcel Goulet Guest

    Thanks, it works well but one thing.

    To fill the subject field, I use (vlax-put-property ..... 'Subject .....)
    To fill the body field, I use (vlax-put-property ..... 'HTMLBody .....)
    To fill the adress field, what do I have to use ?
     
    Marcel Goulet, Jul 19, 2004
    #3
  4. Marcel Goulet

    petersciganek Guest

    You need to use the 'Add method to the Recipients property of the mail i.e.:

    (vlax-invoke-method (vlax-get-property ml 'Recipients) 'Add "")

    - you may well run into security issues here though...

    Peter
     
    petersciganek, Jul 19, 2004
    #4
  5. Marcel Goulet

    Marcel Goulet Guest

    I just find it, it's
    (vlax-put-property ml 'to "")

    Thanks alot.

    Ciao
     
    Marcel Goulet, Jul 19, 2004
    #5
Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments (here). After that, you can post your question and our members will help you out.
Similar Threads

  1. OUTLOOK.EXE

  2. Outlook Express

  3. API-Copy text that is displayed in a message box

  4. SWx 2007 & m$ Outlook 2003

  5. Message Box when dwg opened...

  6. CAD Employment outlook/options

  7. DOH! I created a vba app accross ACAD/EXCEl/OUTLOOK, what do I do with multiple Environments?

  8. Outlook dies and all open .dwg turn read-only

Loading...