Layouts to .DWG

If I have a .dwg file that contains multiple layouts is there a way to produce a separate .dwg file for each of the layouts? I know about the PLT2DWG converter but this is not what we need. Thanks, Mark.

 

SAVEAS ... ?
___

produce a separate .dwg file for each of the layouts? I know about the
PLT2DWG converter but this is not what we need. Thanks, Mark.

 

no tested.

Bruno Toniutti

;;;
;;; LayoutsToDwgs.lsp
;;; Created 2000-03-27

;;; By Jimmy Bergmark
;;; Copyright (C) 1997-2003 JTB World, All Rights Reserved
;;; Website: www.jtbworld.com / http://jtbworld.vze.com
;;; E-mail: /

;;; For AutoCAD 2000
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Creates drawings of all layouts.
;;; Only one layout at a time is saved, the rest are deleted.
;;; This is handy when you want to save to pre A2k versions.
;;; The new drawings are saved to the current drawings path
;;; and overwrites existing drawings.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun c:LayoutsToDwgs (/ fn path msg msg2 fileprefix)
(defun DelAllLayouts (Keeper / TabName)
(vlax-for Layout
(vla-get-Layouts
(vla-get-activedocument (vlax-get-acad-object))
)
(if
(and
(/= (setq TabName (strcase (vla-get-name layout))) "MODEL")
(/= TabName (strcase Keeper))
)
(vla-delete layout)
)
)
)

(vl-load-com)
(setq msg "")
(setq msg2 "")
(command "._undo" "_BE")
(setq fileprefix (getstring "Enter filename prefix: "))
(foreach lay (layoutlist)
(if (/= lay "Model")
(progn
(command "_.undo" "_M")
(DelAllLayouts lay)
(setvar "tilemode" 0)
(setq path (getvar "DWGPREFIX"))
(setq fn (strcat path fileprefix lay ".dwg"))
(if (findfile fn)
(progn
(command ".-wblock" fn "_Y")
(if (equal 1 (logand 1 (getvar "cmdactive")))
(progn
(setq msg (strcat msg "\n" fn))
(command "*")
)
(setq msg2 (strcat msg2 "\n" fn))
)
)
(progn
(command ".-wblock" fn "*")
(setq msg (strcat msg "\n" fn))
)
)
(command "_.undo" "_B")
)
)
)
(if (/= msg "")
(progn
(prompt "\nFollowing drawings were created:")
(prompt msg)
)
)
(if (/= msg2 "")
(progn
(prompt "\nFollowing drawings were NOT created:")
(prompt msg2)
)
)
(command "._undo" "_E")
(textscr)
(princ)
)

 

The latest version can be found here:
http://www.jtbworld.com/lisp/layoutstodwgs.htm

--
Best Regards, Jimmy Bergmark
CAD and Database Developer Manager at www.pharmadule-emtunga.com
Take a look at
JTB FlexReport (FLEXlm report tool) - www.jtbworld.com/jtbflexreport
SmartPurger (Purges automatically) - www.jtbworld.com/?/smartpurger.htm
or download some freeware at www.jtbworld.com
More on AutoCAD 2005;
www.jtbworld.com/autocad2005.htm