'insertion point' of a hatch

Hi,
I would like to list the 'insertion point' of a hatch into a lisproutine. Where can I find the definition of this point, that lightens up when you click on a hatch. Any help is welcome.
André

 

I was looking at this one.

I thought it was but:

The grip that appears when the hatch is selected is not the centroid of the hatch.

I do have a way to get the centroid of the hatch (and the outline of it for that matter).

Bill

 

What is it? I'd sure appreciate it if you share it with us.

 

In my very limited testing it appears that the 'insertion point' is the
center of the hatch's bounding box which can be obtained via the ActiveX
'getboundingbox' method.

 

Jeff, I am not familiar with ActiveX. Is there an easy way to list the coordinates of the grip, so I can use them as an insertion point for my text in a lisproutine?
André

 

maybe like this....
(prompt "\nType >>> hatchpoint <<< to load test prgm\n")
(defun C:hatchpoint ()
(setq oldosm (getvar "osmode"))
(setvar "osmode" 512)
(setq htch (car (entsel "Select hatch only:")))
(setq alist (entget htch))
(if (eq (cdr (assoc 0 alist)) "HATCH")
(progn
;; vertexies for hatch only :
(setq vexs (reverse (cdr
(reverse (cdr
(mapcar 'cdr (vl-remove-if-not
(function (lambda (x)(= (car x) 10)))
alist)))))))

(setq int_point (list
(/ (apply '+ (mapcar 'car vexs))(length vexs))
(/ (apply '+ (mapcar 'cadr vexs))(length vexs))
(/ (apply '+ (mapcar 'caddr vexs))(length vexs))))
)
)
;; TesT part :
(setvar "osmode" 0)
(command "_.line" int_point pause "")
(setvar "osmode" oldosm)
(princ)
)

thank you

 

Thanks for helping, Fatty, but this is what I already had. It doesn't give me the coordinates of the grip of a hatch.
Any other suggestions?

 

Copy the following into your lisp program then to find the point use (setq
grppt(hatchgrip))


(defun hatchgrip (/ obj pt1 pt2 ptg)
(vl-load-com)
(setq obj (objsel "Select Hatch Object: "))
(vlax-invoke-method obj 'GetBoundingBox 'pt1 'pt2)
(setq ptg (midpoint (vlax-safearray->list pt1)
(vlax-safearray->list pt2)
)
)
(setq ptg(trans ptg 0 1))
ptg
)

(defun midpoint (p1 p2)
;;Usage (setq mid(midpoint pt1 pt2))
(mapcar '* '(0.5 0.5 0.5) (mapcar '+ p1 p2))
)

(defun objsel ($prompt / ent obj)
;;usage = (setq obj(objsel "Select Object: "))
(setq ent (car (entsel $prompt)))
(if (/= ent nil)
(setq obj (vlax-ename->vla-object ent))
(princ "No Object Selected")
)
obj
;;returns result for use in calling program
)

 

Andre,

Look at what Dann posted. It is essentially what Jeff suggested. The right idea, IMO.
Though I haven't studied the details.

Joe Burke

 

Dann,
This is exactly what I'm looking for. Many thanks from the Netherlands.
André

 

Joe, also thanks to you for replying, I found a perfect solution with Dann's idea. André

 

No problem, Glad I could help.