File Support Path

Hi

I am making a installable menu system to distribute to my other workers here
at work.

One question,

In one of my programs I need to add 'File Search path' in order for the
program to work.

Is there anyway to add a customized 'File Search Path' or will this always
be a manual process?

Thanks for the help.

 

Max,
This is what I use for a customer:

(defun addSupportPath (dir pos / tmp c lst)
(setq tmp "" c -1)
(if (not (member (strcase dir)
(setq lst (mapcar 'strcase (strParse (getenv "ACAD") ";")))))
(progn
(if (not pos) (setq tmp (strcat (getenv "ACAD") ";" dir))
(mapcar '(lambda (x)
(setq tmp (if (= (setq c (1+ c)) pos)
(strcat tmp ";" dir ";" x)
(strcat tmp ";" x)
)
)
)
lst
)
)
(setenv "ACAD" tmp)
)
)
(princ)
); end function
;;
;;;==================================================================
;;; (StrParse Str Delimiter)
;;; Parses a delimited string into a list
;;;------------------------------------------------------------------
;;; Parameters:
;;; Str String to parse
;;; Delimiter Delimiter to search for
;;;------------------------------------------------------------------
;;; Returns:
;;; A list strings.
;;; ex:
;;; (setq a "Harp,Guiness,Black and Tan")
;;; (StrParse a ",")
;;; returns:
;;; ("Harp" "Guiness" "Black and Tan")
;;;------------------------------------------------------------------
;;; See Also: (StringToList)
;;;------------------------------------------------------------------
(defun strParse (Str Delimiter / SearchStr StringLen return n char)
(setq SearchStr Str)
(setq StringLen (strlen SearchStr))
(setq return '())

(while (> StringLen 0)
(setq n 1)
(setq char (substr SearchStr 1 1))
(while (and (/= char Delimiter) (/= char ""))
(setq n (1+ n))
(setq char (substr SearchStr n 1))
) ;_ end of while
(setq return (cons (substr SearchStr 1 (1- n)) return))
(setq SearchStr (substr SearchStr (1+ n) StringLen))
(setq StringLen (strlen SearchStr))
) ;_ end of while
(reverse return)
) ;_ end of defun
;;
;; Add Delphi Toolkit to Support Path..IF not there..
;;
(addSupportPath "C:\\DELPHITK" nil)
;;

 

Thanks Bob!...I'll give it awhirl

Max

 

Bob, How do you set this lisp you to load multiple support paths?

Thanks,
Chris

 

Chris,
Just add more of these:

Like:
(addSupportPath "C:\\MYBLOCKS" nil)
(addSupportPath "C:\\NEW_STUFF" nil)

Etc.
Bob