Command Alias for Circle Tan Tan Tan?

I use the circle options TTR and TTT alot. I am making a lisp routine to
setup aliases for those comands (2p and 3p as well). Because Circle Tan Tan
Tan is not an option in the cirlce command I can't figure out how to do it.

Here is what I have:

;Circle - Tangent Tangent Radius
(defun C:ct ()
(command "circle" "t" )
(princ))

;Circle - 2 Point
(defun C:c2 ()
(command "circle" "2p" )
(princ))

;Circle - 3 Point
(defun C:c3 ()
(command "circle" "3p" )
(princ))

;Circle - Tangent Tangent Tangent
(defun C:ctt ()
(command "circle" "3p" (getpoint "tan")(getpoint "tan")(getpoint "tan")
(princ))

I don't know much about lisp, but do my best.

Any help would be much appreciated.

Chris

 

Here's the macro used by the menu:

^C^C_circle _3p _tan \_tan \_tan \

 

Yea, I tried inserting that into my lisp - but it didn't work for me. Maybe
I am doing something wrong.

 

It's not going to be a direct drop-in. You'll need to set up the tangent
snap and use the pause function to acquire user input.

 

What Frank gave was a menu macro not a lisp. In lisp you could do this.

(defun c:CTT(/ oos1)
(setq oos1 (getvar "osmode"))
(setvar "osmode" 256)
(command "_.circle" "_3p" pause pause pause)
(setvar "osmode" oos1)
(princ)
)

or

(defun c:CTT (/ pt1 pt2 pt3 oos1)
(setq oos1 (getvar "osmode"))
(setvar "osmode" 256)
(setq pt1 (getpoint "\n Select first tangent point: "))
(setq pt2 (getpoint "\n Select second tangent point: "))
(setq pt3 (getpoint "\n Select third tangent point: "))
(if (and pt1 pt2 pt3)
(command "_.circle" "_3p" pt1 pt2 pt3)
)
(setvar "osmode" oos1)
(princ)
)

I would prefer the second one.

Tim

 

OK - TIM - That all makes sense. Like Isaid I don't know much about
writting lisps, but I'm trying to learn on the fly.

Thanks!
Chris

 

Chris,

No problem, happy to help. This NG has been one of the most beneficial learning places for me, so when I can help I like to, as do almost all people here.

Tim

 

Thanks, I can make use of this to.

Gary

learning places for me, so when I can help I like to, as do almost all people
here.

 

Hi Tim

It's recommendable to check each user input and add error handling...¦-)

Code:

(defun C:CTTT ( / pt1 pt2 pt3 ocmd oos1 *Error*)
(setq oos1 (getvar "OSMODE")
ocmd (getvar "CMDECHO")
)
(defun *Error* (Msg)
(setvar "OSMODE" oos1)
(setvar "CMDECHO" ocmd)
(if Msg (princ Msg))
(princ)
)
(setvar "OSMODE" 256)
(cond
((not (setq pt1 (getpoint "\nSelect 1st tangent point: "))))
((not (setq pt2 (getpoint "\nSelect 2nd tangent point: "))))
((not (setq pt3 (getpoint "\nSelect 3rd tangent point: "))))
(T
(setvar "CMDECHO" 0)
(command "_.CIRCLE" "_3P" pt1 pt2 pt3)
)
)
(*Error* nil)
)

Cheers

 

You can avoid having to mess with osmode by putting it in the command call:
(command "._circle" "_3P" "_tan" PAUSE "_tan" PAUSE "_tan" PAUSE)
But, as shown in Jürg's function, you may still want to suppress cmdecho.