1-2-3 to A-B-C

I have written this very simple lisp for updating our standard grid block by picking (1st picked attribute changed to 1, second picked changed to 2 and so on...)

What would be the best way to do this but change grids alphabetically
(1st picked attribute changed to A, second picked changed to B and so on...)

(if (= sn 1) (setq sl A)) seems to be in the right direction I think but im having trouble getting it to work,

Anyones help would be greatly appreciated,



(defun c:gridnos (/ sn)
(setq sn (getint "\nStart Number: "))
(while sn
(command "attedit" "y" "*" "*" "*" PAUSE "" "v" "r" sn "")
(setq sn (1+ sn))
)
)


Thanks

 

Try this:

(defun alphet (cnt / m)
(setq alfavitum '("Ð" "B" "C" "D" "E" "F"
"G" "etc."))
(setq m (nth (1- cnt) alfavitum))
)

 

Sorry for my ingorance but I can't see what that does. How do I write that into my lisp?

 

Don't have time to work out the details, but the (chr) lisp function will do
it:

(setq letter 65)

makes A the first character (ASCII code for capital A is 65).

Apply (chr letter) in place of your sn in the attedit part, to make A the
text content of the attribute. Then increment it upward with

(setq letter (1+ letter))

and go to the next one, etc.

Kent Cooper, AIA


...

 

(defun c:gridnos (/ sn)
(setq sn (getint "\nStart Number: "))
(setq alp_lst (list "A" "B" "C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "R" "S" "T" "U" "V" "W" "X" "Y" "Z")
)
(while sn
(setq new_alp (nth (1- sn) alp_lst)
)
;(command "attedit" "y" "*" "*" "*" PAUSE "" "v" "r" new_alp "")
(princ "\n ")(princ new_alp)
(setq sn (1+ sn)
new_alp (nth sn alp_lst)
)
(if (> sn 26)(exit))
)
)


Bill

 

Bill, I allready got it using juerg's method..

Thanks anyway, I did adopt the start letter option from yours, this is what I ended up with

(defun c:gridlet (/ sn letter)
(setq letter (getint "\nStart Number: A=1 B-2 ETC... "))
(setq letter (+ 64 letter))
(while letter
(setq sn (chr letter))
(command "attedit" "y" "*" "*" "*" PAUSE "" "v" "r" sn "")
(setq letter (1+ letter))
)
)

The only problem is that is if you do not select directly on the attribute is stops working as sn becomes nil. I'd like a way to force the lisp to work until esc. is pressed in case the user misses a pick... Any ideas?

 

I can't test this idea right now but errno = 52 I believe is for "enter".

(while (and letter (/= (getvar "errno") 52)))

Let me know if it works.

Bill

 

I hope you'll understand me
I had change your function a lot, it works correct,
but it change visible attributes only

(defun c:gridnos (/ sn)
(defun alphet (cnt / m)
(setq alfavitum (list "A" "B" "C" "D" "E" "F"
"G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q"
"R" "S" "T" "U" "V" "W" "X" "Y" "Z")
)
(setq m (nth (1- cnt) alfavitum))
) ;eof alphet

;your function:
(setq sn (getint "\nStart Number: "))
(while sn
; here put minus symbol before attedit
; to ignore "Edit Attributes" dialog window
(command "-attedit" "y" "*" "*" "*" pause "" "v" "r" (alphet sn) "" "")
(princ "\n ")(princ (alphet sn))
(setq sn (1+ sn))

(if (> sn 26)(exit))
(princ)
)
)

Fatty ;v)

 

I tried with it but couldnt' get it going, Ill have another look later when I have more time and let you know

 

Try this. The only thing is it only works with one value entered.

Tim

(defun c:CntText (/ cnt1)

(command "_.undo" "_end")
(command "_.undo" "_group")
(vl-load-com)
(setq cnt1 (getstring "\n Enter starting string: "))
(if cnt1
(AddString cnt1)
)
(command "_.undo" "_end")
(princ)
)

(defun AddString (num1 / ent1 ob1)

(setvar "errno" 0)
(while (and (not ent1) (/= (getvar "errno") 52))
(setq ent1 (nentsel "\n Select text/attribute to change: "))
(if ent1
(progn
(setq ob1 (MakeX (car ent1)))
(PutX ob1 'Textstring num1)
(setq num1 (chr (1+ (ascii num1))))
(setq ent1 nil)
)
)
)
)

(defun MakeX (entname)
(vlax-ename->vla-object entname)
)

(defun PutX (object prop val)
(if (vlax-property-available-p object prop T)
(vlax-put object prop val)
)
)

 

Great routine.
Question, how could you modify the code to also add a zero before digits 1 thur 9
to the text string value.


(strcat 0 cnt1)

Gary

 

You can try this.

Old
(setq ob1 (MakeX (car ent1)))
(PutX ob1 'Textstring num1)
(setq num1 (chr (1+ (ascii num1))))

New
(setq ob1 (MakeX (car ent1)))
(if (> 49 (ascii num1) 57)
(PutX ob1 'TextString (strcat "0" num1))
(PutX ob1 'Textstring num1)
)
(setq num1 (chr (1+ (ascii num1))))

Untested, but I think it should work.
Tim

 

hummm............I cant get it to work
stops after the first pass, without strcat the zero

(if (> 49 (ascii num1) 57)

I tried
(if (and (> 49 (ascii num1))(< (ascii num1) 57))

Gary

 

Gary,
This should work now.

Tim

(defun AddString (num1 / ent1 ob1)

(setvar "errno" 0)
(while (and (not ent1) (/= (getvar "errno") 52))
(setq ent1 (nentsel "\n Select text/attribute to change: "))
(if ent1
(progn
(setq ob1 (MakeX (car ent1)))
(if (<= 49 (ascii num1) 57)
(PutX ob1 'TextString (strcat "0" num1))
(PutX ob1 'Textstring num1)
)
(setq num1 (chr (1+ (ascii num1))))
(setq ent1 nil)
)
)
)
)

 

Thanks..I learned a lot, by studing your code.

Gary

 

Cool glad I could help.

Tim